Today I thought about my problem of having my old site still 1/2 alive next to my new WordPress site. On the internet there are still a couple of links that directly point to various files that aren’t used anymore. Wouldn’t it be nice if you could just remove all those old files and still come up with the right WordPress page?
I just made this possible by changing my custom 404 urlrewrite page. This is what my page now does:
1. get whatever is after the domain name from the url and open the wordpress index.php with that part behind it.
2. if the result is not a regular page, then get the words from the url and perform a search.
for instance the link http://evict.nl/error will search for the word error because there is no page named error. One of my old pages http://evict.nl/comdoc/default.asp will now search for ‘comdoc’ and still find the comdoc content (below this post).
Here is the complete sourcecode of my error.asp
<%
Response.Buffer = True
Response.Status = "200 OK"
Response.CharSet = "UTF-8"
Session.CodePage = 65001
myurl = QueryPath()
content = ReturnPage(myurl)
notfound = "Sorry, but you are looking for something that isn't here. You can search again by using the form on upper right of the page..."
if instr(content, notfound) > 1 or len(trim(content)) < 1 then
Response.Write ReturnPage(SearchQueryPath())
else
Response.Write content
end if
Response.End()
Function QueryPath()
' The WordPress location
w = "http://" + Request.ServerVariables("HTTP_HOST") + "/index.php"
' Take whatever is after the host name
q = mid(request.QueryString, instr(request.QueryString, Request.ServerVariables("HTTP_HOST")) , 999)
' Take the part behind the first /
QueryPath = w + mid(q, instr(q, "/") , 999)
End Function
Function SearchQueryPath()
' The WordPress location
w = "http://" + Request.ServerVariables("HTTP_HOST") + "/index.php?submit=Find&s="
' Take whatever is after the host name
q = mid(request.QueryString, instr(request.QueryString, Request.ServerVariables("HTTP_HOST")) , 999)
' Take the part behind the first / and remove all / and \
c = LCase(replace(replace(mid(q, instr(q, "/") + 1 , 999),"/"," "),"\"," "))
' Remove the default.asp or .asp or .
SearchQueryPath = w + replace(replace(replace(c,"default.asp",""),".asp",""),"."," ")
End Function
Function ReturnPage(myPage)
on error resume next
br = Request.ServerVariables("HTTP_USER_AGENT")
set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP")
xmlhttp.open "GET", myPage, false
xmlhttp.setRequestHeader "Content-Type", "text/HTMI"
xmlhttp.setRequestHeader "CharSet", "UTF-8"
xmlhttp.setRequestHeader "User-Agent",br ' Required for the WPtouch iPhone Theme
xmlhttp.send ""
if err.number <> 0 then
Response.Status = "404 Page not found"
ReturnPage = "404 Page not found"
else
ReturnPage = xmlhttp.responseText 'responseBody
end if
set xmlhttp = nothing
End Function
%>
Comments